View source for Audio Monitoring - Scanning

{{AI}}
This application makes it possible to silently monitor in sequence a dynamically selected group of stations. The scanning can be paused, and one can listen to one particular station. In stations with DAK panel with LED ([[CRM-V]] and [[ECPIR-3P]]), the green will show which station that is currently monitored. In addition, the station display shows which station is currently being monitored.

The application is using the [[Simplex Conference]] feature.

==Operation==
There are 3 dedicated DAK keys for this function. The programming example in this article is using Dak 1-3.
* DAK 3 (D3): '''Select Stations key'''. Press D3, then select stations to be monitored by pressing the corresponding DAK key (or dialling the directory number). Red LED shows selected stations. Press D3 (or C-key) to terminate the selection.
* DAK 1 (D1): '''Start/Pause key'''. Press D1 to start the scanning. The system will start to monitor in rotating order, 2.5 seconds (configurable) at each station. Green LED shows currently monitored station. During the scanning, you can pause at one particular station by pressing D1. Resume scanning by pressing D1 again. 
* DAK 2 (D2): '''Stop key'''. Press D2 to stop scanning and clear the scanning group selection

== Prerequisites ==
* ICX-AlphaCom server, or AlphaCom XE with firmware AMC 13.0.3.0 or later
* The directory number of the master station must be in the range of 1 - 6000.

==Master Station configuration==
Any master station can be used to perform the scanning, however when using a station with DAK panel with LEDs ([[CRM-V]] and [[ECPIR-3P]]), one will have a visual indication by red LED of which stations are selected for monitoring, and green LED showing which station is currently being monitored.

===DAK Programming===
The master station is using these DAK keys:
* DAK1 = Leave blank in the DAK table (key press is triggering event 30)
* DAK2 = Leave blank in the DAK table (key press is triggering event 30)
* DAK3 = 9535 ([[Event_Trigger_w/User_Parameter|Two-step event trigger]]. 9535 by default)

=== Simplex Conference and Station Group ===
From AlphaPro, select [[Users_%26_Stations_(AlphaPro)#UDP_tab|Users & Stations > UDP tab]]:
* Include the master station in UDP group 1. 
* In the '''User Defined Parameter''' field, enter the ''index number'' of the simplex conference AND the station group to be used by this master station. Valid range 1 - 50. If you for example enter "20", then station group 20 will be used for the station selection, and simplex conference 20 (8220) will be used for the monitoring. It is recommended to use a fairly high number, say 16 or higher, to avoid conflict with group calls or conferences used for other purposes.
[[File:Scan master udp.PNG|thumb|left|500px|Use conference 20 and group 20 for the scanning feature]]
<br style="clear:both;" />


The master station must be set as Default Member of the conference.

From AlphaPro, open [[Simplex_Conferences_(AlphaPro)|Simplex Conferences]] window, select the conference as defined in the '''User Defined Parameter''' field above, and set the master station as Default Member.

[[File:Scan DefMmbr.PNG|thumb|left|500px|The master station is set as Default Member of conference 20]]
<br style="clear:both;" />

==Event Handler Programming==
A number of UDD variables are used:
* UDD = Physical number of master station: "Next Member" UDD. Stores the physno of the next station in the scanning group
* UDD = Directory number of master station: Scanning State. 0 = Scanning is running. 1 = Scanning is paused

{{note|
* ''Almost all events are made generic, so one can copy/paste into a new database without any modifications. However, there are two considerations:''
* ''The Directory number of the master station must be entered in the [[#Scanning indication|Scanning indication]] event ''
* ''The Scanning Interval can be modified in the [[#Scanning routine|Scanning routine]] event'' }}

===Initialization ===
When the master station goes online (event 13, OFF), empty the scanning group by the $GRM command.
[[File:Init scanning2.PNG|thumb|left|500px|Initialization]]
<br style="clear:both;" />

{{Code2|
 $GRM LV NG%1.exp U3
}}

=== Select stations - Start event ===
When DAK 3 - "Select Scanning Group" (9535) is pressed, set "Scan State" UDD = "Running". Turn on red LED in the DAK key, and write some help text to the display.
[[File:Scan event2.PNG|thumb|left|500px|Event 2]]
<br style="clear:both;" />

{{Code2|
 WUDD %1.dir 0
 IND %1.phy %1.dak(I%2.dir) 1 1
 $DTS L%1.dir 'Select cell' U1
}}

=== Select stations ===
After having pressed DAK 3, this event 25 is triggered every time a new directory number is dialled. 
* If the dialled number is 9535, it means DAK 3 is pressed again, and the selection mode is terminaled ([[DISCON_ST|$DISCON_ST]]).
* If the dialed number is included (%sgm) in the group specified in UDD 1000, it will be removed from the group ([[$GRM]]). Red LED in associated DAK key will be turned off.
* If the dialed number is not included (%sgm) in the group specified in UDD 1000, it will be included in the group ([[$GRM]]). Red LED in associated DAK key will be turned on.

[[File:Scan event3.PNG|thumb|left|500px|Event 3]]
<br style="clear:both;" />

{{Code2|
 IF %op(%2.dir,<nowiki>=</nowiki>,9535)
 $DISCON_ST L%1.dir U2
 stop
 ENDIF
 IF %sgm(%2.phy,%1.exp)
 $GRM L%2.dir NG%1.exp U0
 IND %1.phy %1.dak(I%2.dir) 1 1 OFF
 stop
 ENDIF
 $GRM L%2.dir NG%1.exp U1
 IND %1.phy %1.dak(I%2.dir) 1 1 ON
}}

=== Start/Pause scanning ===
DAK 1 will trigger event 30, subevent 1, ON.
* If the scanning group is empty, scanning will not be started. Write to the display that the user must add stations to the group.
* If the current "Scanning State" is "Running", then toggle the mode to "Paused", and stop the timer that is used for stepping to the next station. Write status to the display.
* If the current "Scanning State" is "Paused", then toggle the mode to "Running", and restart the timer that is used for stepping to the next station. Write status to the display.
[[File:Scan Event_4.PNG|thumb|left|500px|Event 4]]
<br style="clear:both;" />

{{Code2|
 IF %op(%gns(%1.exp,0),<nowiki>=</nowiki>,0)
 $DTS L%1.dir 'D3: Add stations..' U1
 stop
 ENDIF
 IF %udd(%1.dir)
 WUDD %1.dir 0
 $ST L%1.dir W0 L9991
 $DTS L%1.dir 'Scanning paused' U1
 stop
 ENDIF
 WUDD %1.dir 1
 $ST L%1.dir W1 L9991
 $DTS L%1.dir 'Scanning...' U1
}}

=== Scanning routine ===
This timer event is used to step to the next station in the group after a preset time. 
* First the conference is turned off to all stations in the group
* Use [[%gns]] to search the group for members. If there are more members in the group, set the station in "silent call mode" (no LED on), turn on conference ([[$CONF]]) on the next member, and store this station in UDD = physno ([[WUDD]])
* Restart the timer ([[$ST]]), which will trigger this same event at timeout
* Force the next station to feed audio in the conference ([[CONF_TALK|$CONF_TALK]])
* If there are no more members in the group, set reset "Next Station" UDD to 0, and restart this event by starting the timer using a very short time (100ms).
[[File:Scan_Rut_Event_5.PNG|thumb|left|500px|Event 5]]
<br style="clear:both;" />

{{Code2|
 $CONF NG%1.exp LV
 IF %gns(%1.exp,%udd(%1.phy))
 $SC L%rdir(%gns(%1.exp,%udd(%1.phy)))
 $CONF N%gns(%1.exp,%udd(%1.phy)) NC%1.exp
 WUDD %1.phy %gns(%1.exp,%udd(%1.phy))
 $ST L%1.dir W25 L9991
 $CONF_TALK N%udd(%1.phy)
 stop
 ENDIF
 WUDD %1.phy 0
 $ST L%1.dir W1 L9991
}}

{{note| The line " $ST L%1.dir '''W25''' L9991" specifies the scanning interval to 2.5 seconds. Change this value if shorter or longer intervals are required }}

=== Stop scanning ===
DAK 2 will trigger event 30, subevent 2 ON. 
* Stop the scanner timer, and turn off conference on all stations in the scanning group
* Turn off all indications in the DAK keys, and restore the display text to standard
* Empty the scanning group

[[File:Scan_Stop_6.PNG|thumb|left|500px|Event 6]]
<br style="clear:both;" />

{{Code2|
 $ST L%1.dir W0 9991
 $CONF NG%1.exp LV
 IND %1.phy 0 0 0 OFF
 $DTS L%1.dir
 $GRM LV NG%1.exp U3
}}

=== Scanning indication ===
The Simplex Conference event is used to turn on green LED in the DAK key of the station associated to the scanning. In addition, it will write to the display of the master station which station is currently being scanned.
[[File:Scan event7.PNG|thumb|left|500px|Event 7]]
<br style="clear:both;" />

{{Code2|
 OWN r 101
 IND %2.phy %2.dak(I%1.dir) 2 1
 IF %chg(1,0)
 $DTS L%2.dir 'Scanning....' U1
 $DTS L%2.dir '%1.dir %1.nam' U2
 ENDIF
}}

{{note| The line "OWN r '''101'''" specifies number 101 to be the directory number of the master station. Must be modified according to the actual directory number of the master station. (The [[OWN|OWN command]] modifies the "Related To" number of the event).}}



[[Category:AlphaCom Applications]]
[[Category:ICX-AlphaCom Applications]]
[[Category:Control Room Applications]]