Call History (ICX-AlphaCom)

It is possible to store a Call History for a Master Station, and review this history for Call Direction, Time and Directory Number.

Call History

Pre-requisites

• 1 Dummy Station for each Master Station, with prefix 5
  • If your Master Station is 101, you need a Dummy Station with Directory Number 5101
  • This dummy does not need to be an IP Dummy, so CCoIP can be left unchecked. It just needs to be a free physical position with the current number.
• 2 UDP Groups
  • UDP 1 for the Master Station
  • UDP 2 for the Dummy Stations
• UDD's for the Physical Number of the Dummy Station, plus the Dummy Physical offset by 552
  • If your dummy station is Phy 501, you are using UDD 501 + UDD 1053
• Event Trigger 9533 is used to call up the list
• Event Trigger 9534 is used to clear the display
• Event Trigger 9535 is used to clear the call history
  • You need to add the Event Triggers using either with or without cancel tone features (52 - Event Trigger without Cancel Tone or 85 - Event Trigger with Cancel Tone)

Principle

As each call action is handled (Incoming, Outgoing or Missed calls), a Text mail is stored in the dummy station.

When the Event Trigger 9533 is dialed, the mail list in the dummy is copied to the Master Station in reverse order.

The display format is Call Direction, Time and Directory Number

• -> for incoming
• <- for outgoing
• -X for missed

The last 20 call events are stored.

Depending on the mode of the Master Station, the user can either scroll the queue using 7 & 9 after dialing 70 to access the mail menu or using the Next and Top keys in CRM mode.

Show

Once the user has viewed the list, they can clear away the list or clear the call history.

Limitations

In order to provide a true list of calls, including calls to/from the same number, the mail messages have null as the sender.

Using mail with a sender restricts the list to only 1 entry from that sender, as a queue can only have one entry from each station.

It is therefore not possible to call back to the mail due to the use of Text Mail with no sender.

Events

Conversation Incoming

Store the Time and Directory Number of the incoming caller

$STM LV L5%1.DIR U35 '-> %clk(8) %2.DIR'

Conversation Outgoing

Store the Time and Directory Number of the outgoing call

$STM LV L5%1.DIR U35 '<- %clk(8) %2.DIR'

Private Ringing Outgoing

Store the Time and Directory Number of the missed call

IF %op(%sev,=,1)
STOP
ENDIF
$STM LV L5%2.DIR U35 '-X %clk(8) %1.DIR'

Received Mail ON

Track the number of mails stored at the dummy number and tail off the oldest call if there are 21 mails waiting

WUDD %1.PHY %op(%udd(%1.phy),+,1)
IF %op(%udd(%1.phy),==,21)
$MAILQ_NAVIG L%1.DIR U0
ENDIF

Received Mail OFF

Decrement the counter of mails at the dummy number

WUDD %1.phy %op(%udd(%1.phy),-,1)

Event Trigger Feature - 9533

Start the process of copying the mails from the dummy number to the Master Station by selecting the last mail at the dummy number

WUDD %op(%rphy(5%1.dir),+,552) 1
$MAILQ_NAVIG L5%1.DIR U3

Event Trigger Feature - 9534

Delete all waiting mails at the Master Station, used to clear the Call History from the Master Station

$CANM LV L%1.DIR

Event Trigger Feature - 9535

Delete all waiting mails at both the Master Station and the dummy number to clean the history.

$CANM LV L%1.DIR
$CANM LV L5%1.DIR
WUDD %op(%rphy(5%1.dir),+,552) 0

New Current Mail

The looping process that copies mails in reverse order back to the Master Station by re-triggering this event when selecting the previous mail in the list

IF %op(%udd(%op(%1.phy,+,552)),==,0)
STOP
ENDIF
$CPYM L%1.DIR W%2.TAG L%1.DIR(3)
IF %op(%udd(%op(%1.phy,+,552)),==,%udd(%1.phy))
WUDD %op(%udd(%1.phy),+,552) 0
STOP
ENDIF
$MAILQ_NAVIG L%1.DIR U7
WUDD %op(%1.phy,+,552) %op(%udd(%op(%1.phy,+,552)),+,1)