Audio Monitoring - Scanning

This application makes it possible to silently monitor dynamically selected stations in a sequence. The green LED in the DAK panel will show which station that is currently monitored. The guard in the Control Room can pause the scanning and listen to one particular station.

The example described consists of:

• 1 CRM-V w/D48; Dir no: 101
• 5 IP Substations; Dir no: 111-115

Operation

• To select stations to be monitored, press the Scanning DAK (D3), then select the stations by pressing the DAK key they are configured on (or dialling the directory number). Finish the selection phase by pressing the Scanning DAK again.
• To start silently monitor multiple stations, press DAK 1 (D1). The system will start to monitor in rotating order.
• To stop the scanning, press DAK 2 (D2).
• To stop the scanning and listen to a particular station, press DAK 1 (D1).

DAK Programming

The CRM has these DAK keys configured:

• DAK5-9 = Substation(111-115)
• DAK1 = Start scan/pause
• DAK2 = Stop scan
• DAK3 = Select stations to be scanned (9535)

Simplex Conference

• Conference number 1 - Deafult member: 101 Control Room

Station configuration

Put the CRM station in a UDP group and define the chosen simplex conference in the EXP field.

Put all the stations that should be able to be scanned in a common UDP group.

Event Handler Programming

Start Selection Event: This event trigger immediately when the Scanning DAK is pressed. Turns on a LED and writes to the display.

Action commands:

IND %1.phy %1.dak(I%2.dir) 1 1 ON
$DTS L%1.dir 'Select cell' U1

---

Selection Event: This is a two-step event trigger that adds any selected station to group 16.

Action commands:

IF %op(%2.dir,=,9535)
IND %1.phy %1.dak(I%2.dir) 1 1 OFF
WUDD %1.dir 2
$DISCON_ST L%1.dir U2
STOP
ENDIF
$GRM L%2.dir NG16 U2
IF %udd(%2.phy)
IND %1.phy %1.dak(I%2.dir) 1 1 OFF
WUDD %2.phy 0
STOP
ENDIF
IND %1.phy %1.dak(I%2.dir) 1 1 ON
WUDD %1.dir 3
WUDD %2.phy 1

---

Start Scanning Event: Starts a 0.1 sec timer. If pressed while Scanning is running, then pause.

Action commands:

IF %op(%udd(%1.dir),=,3)
$DISCON_ST L%1.dir U3
STOP
ENDIF
IF %op(%udd(%1.dir),=,2)
WUDD %1.dir 1
$ST L%1.dir W1 L9991
IND %1.phy 1 1 3 OFF
STOP
ENDIF
IF %op(%udd(%1.dir),=,1)
WUDD %1.dir 2
$ST L%1.dir
IND %1.phy 1 1 3 ON
$DTS L%1.dir 'Scan: Paused'
STOP
ENDIF
WUDD %1.phy 0
WUDD %1.dir 1
$ST L%1.dir W1 L9991
IND %1.phy 1 1 1 ON

---

Scan Timeout Event: Clears current monitored station, starts monitoring of new station, set a 2.5 sec timer.

Action commands:

$CONF NG16 L8200
tmp 0 "%gns(16,%udd(%1.phy))"
tmp 1 "%rdir(%tmp(0))"
IF %op(%tmp(0),=,0)
tmp 0 "%gns(16,0)"
tmp 1 "%rdir(%tmp(0))"
ENDIF
WUDD %1.phy %tmp(0)
$CONF L%tmp(1) L%1.exp U2
$CONF_TALK L%tmp(1) U2 U1
$ST L%1.dir W25 L9991
$DTS L%1.dir 'Scan: Running' U1

---

Stop Scan Event: Stops the scanning, clears the timers and empties the scanning group.

Action commands:

$ST L%1.dir
$CONF NG16 L8200
IND %1.phy 1 1 1 OFF
WUDD %1.dir 0
$ST L%1.dir W1 L9992
$ER U15 U0 U1 U1 N%gns(16,0) U3 L9993

---

Cleanup Event: Empties the scanning group after scanning is stopped.

Action commands:

IF %gns(16,0)
tmp 0 "%gns(16,0))"
tmp 1 "%rdir(%tmp(0))"
$GRM N%gns(16,0) NG16 U0
$ER U15 U0 U1 U1 N%gns(16,0) U3 L9993
OWN 101
IND %1.phy %1.dak(I%tmp(1)) 1 1 OFF
ENDIF

---

Cleanup Event2: Cleans up the display after scanning is stopped.

Action commands:

$DTS L%1.dir

---

Scanned Stations Event: Updates LED status on the DAK panel as stations are scanned. Also turn station LED off.

Action commands:

OWN r 101
IND %2.phy %2.dak(I%1.dir) 2 1
$DTS L%2.dir '%1.nam' U2
pause
$DIP L%1.dir "ind stl 0 0"
$DIP L%1.dir "stinfo 5 'LedOff'"

---