Self Testing Call Button (ICX-AlphaCom mode)

The Vandal Resistant intercom - VR3G-1P features a Self Testing Call Button. The Event Handler is used to activate the call button and report the results.

The Piezo button of the VR3G-1P has internal circuitry that will physically activate the call button as if someone has pressed it. This allows for full testing of the stations operating when used in conjunction with Tone Testing.

Pre-requisites

• All setup items can be changed as required
• All VR3G-1P stations must be in UDP group 1
• All VR3G-1P stations must be in Station Group 11
• Station Group 12 must be reserved and not populated
• Each VR3G-1P station will use an UDD attributed to it's physical number
• All VR3G-1P stations must be assigned a RCO related to it's Physical Number and Pin 3

Principle

• During Self Test, all stations from Group 11 are copied to Group 12
• One by one, stations from group 11 have their UDD set, and will activate their Self Testing Output (I/O Pin 3)
• When DAK as RCI is triggered from the button press, the station will note that their UDD is set, and remove themselves from Group 12 prior to resetting their UDD
• After the test run is complete, an Event Timeout will report the members of Group 12 who did not press their button, indicating a fault

Set I/O Pin 3 as Output

Log into the station webserver and navigate to the I/O Settings. The Self Test feature is from factory wired to output 3.

Choose I/O Pin 3 and set it as Output.

Events

Start Self-test

The self-test can be started in several ways, e.g. an operator pressing a DAK key or a Scheduled event. In the example below it is started by the operator pressing DAK 1 (event 30, sub-vent 1):

DAK Settings

Action commands:

LOG "Test Call Buttons"
$GRM NG11 NG12 U1
tmp 0 "%gns(11, 0)"
LOOP
IF %op(%tmp(0),=,0)
LOG "Test completed. Check results"
$ST L101 W50 L9999
BREAK
ENDIF
WUDD %tmp(0) 1
LOG "Test Physical #%tmp(0)"
IF %op(%busy(%tmp(0)),==,0)
RCO %tmp(0) ON 25
ENDIF
IF %op(%busy(%tmp(0)),==,1)
LOG "Physical #%tmp(0) busy. Skipping"
WUDD %tmp(0) 0
$GRM N%tmp(0) NG12 U0
ENDIF
tmp 0 "%gns(11, %tmp(0))"
ENDLOOP

Self-test execution

When output 3 of the station is activated (in previous event), it will trigger the self-test feature of the piezo-button, activating input 1 (event 30, sub-event 11):

DAK Settings

Action commands:

IF %udd(%1.phy)
LOG "Button Test OK %1.dir %1.nam"
$GRM L%1.dir NG12 U0
WUDD %1.phy 0
STOP
ENDIF
$DD L%1.dir L6701

Report Results

DAK Settings

Action commands:

LOG "Check for button failures"
tmp 0 "%gns(12,0)"
LOOP
IF %op(%tmp(0),=,0)
BREAK
ENDIF
own %rdir(%tmp(0))
LOG "Button failure %rdir(%tmp(0)) %1.nam"
tmp 0 "%gns(12,%tmp(0))"
WUDD %tmp(0) 0
ENDLOOP