Actions

Visitor Intercom - Remote call setup and Listen-In

From Zenitel Wiki

Revision as of 17:04, 15 October 2021 by Asle (talk | contribs) (Event Trigger directory numbers)
Icx icon.png
Overview

This article describes how the ICX-AlphaCom system can be configured to control call setup between pairs of stations, e.g. used for visitor intercoms i prison, interrogation rooms etc. Up to 20 pairs of intercoms are supported.

From the Control Room Station one can:

  • Set up and tear down calls between two stations in a "pair"
  • Silently Listen-In on an active conversation
  • Start/stop recording of active calls. This requires that a Zenitel Audio Recorder is installed.


Operation

The application is based on using the IP Flush Master with a DAK-48 module. One DAK panel supports up to 16 pairs of intercoms. If more pairs are needed (max. 20 pairs), a second DAK-48 panel must be added. Function keys on the DAK48 panel will be as follows:

DAK-48 panel layout





  • Call setup: Press the "Pair x" button. The two intercoms in the pair will be connected, and the green LED will be lit. Press the button again to terminate the connection. One can activate as many pairs as one wants.
  • Listen-In: Press the "Listen x" button to silently monitor the conversation in the selected pair. Press the same button again (or C-button) to stop Listen-In. Only one conversation can be monitored at a time. If pressing a new "Listen x" button, the current monitoring will be terminated, and the new selection will be activated. Active Listen-In is indicated by green LED. One can start the "Listen-In" before or after a call has been set up. Talkback into the conversation is possible by pressing the M-key while talking.
  • Audio Recording: Press the "REC x" button to start audio recording of the conversation in the selected pair. Recording can be started only after the call has been set up. An active recording is indicated by red LED. Multiple conversations can be recorded at the same time.


Note icon Due to the nature of Voice over IP (VoIP), there will be some audio delay between Station A and B. Please note that:
  • If users of Station A and B can hear each other also through the air (e.g. over a glass wall or through a thin wall), they might experience echo effect
  • If users of Station A and B can see each other (e.g. through a glass wall), they might experience that audio is not in synchronization with the lips of the talker (missing lip sync).


Number plan

The application is using the Duplex Conference feature of the ICX-AlphaCom. There are 20 conference channels, default numbers are 8301-8320.

General rules

Due to the Event Handler configuration used in this application, a strict number plan must be followed.

  • Each intercom pair is using one fixed duplex conference.
  • The "Call setup", "Listen-In" and "Record" are Event Triggers, feature 52.

The general directory number rules are as follows:

  • Intercom pair xx:
    • Conference number: 83xx
    • Station A: 41xx
    • Station B: 42xx
    • Call Setup: 43xx
    • Listen-In: 44xx
    • Record: 45xx
  • Example - Pair 4:
    • Conference number: 8304
    • Station A: 4104
    • Station B: 4204
    • Call Setup: 4304
    • Listen-In: 4404
    • Record: 4504

Station directory numbers

The Control Room Station must have directory number 4000.

The stations in the pairs must have directory numbers 41xx (Station A) and 42xx (Station B) according to the rules above.

Station directory numbers



Station A in each pair must be included in UDP group 1. Note that "Station B" must not be in the UDP group.

Station A in each pair must be in UDP group 1



Event Trigger directory numbers

Event Trigger numbers must be created in AlphaPro, Directory & Features menu as Event Trigger, feature 52.

Note that the ID field is used to separate the events. The ID field is linked to the Sub-Event field in the Event Handler.

  • Call Setup: 43xx. ID field = 1.
  • Listen-In: 44xx. ID field = 2.
  • Record: 45xx. ID field = 3.
Event Trigger directory numbers


DAK-48 panel configuration

If more that 20 DAK keys are used, one have to "borrow" DAK tables from free users.

Note that the Event Trigger numbers must be entered with the letter "E" in front:

The first six DAK keys The 4 first DAK keys are D1-D4 on the main module)


Below shows which numbers should be assigned to the first 24 DAK keys on the panel:

The first 24 DAK keys



Event Handler configuration

Call Setup event

Event Triggered by 43xx codes


IF %udd(%2.dir(2))
$ODC L41%2.dir(2,0) L8300
IND %1.phy %1.dak(E%2.dir) 2 1 OFF
stop
ENDIF
$ODC L41%2.dir(2,0) L83%2.dir(2,0)
IND %1.phy %1.dak(E%2.dir) 2 1 ON


"Station B" will follow "Station A" in/out of conference


$ODC L42%1.dir(2,0) L%chg(%2.dir,8300)
WUDD %1.dir(2) %chg(1,0)
IF %chg(0,1)
IF %udd(1%2.dir(2,0))
$REC L%2.dir U0
WUDD 1%2.dir(2,0) 0
OWN 4000
IND %1.phy %1.dak(E45%2.dir(2,0)) 1 3 OFF
ENDIF
ENDIF


Listen-In event

Event Triggered by 44xx codes


IF %op(%2.dir,=,%udd(5000))
$DISCON_ST L%1.dir U0
WUDD 5000 0
stop
ENDIF
$SNV Q0 W1 W6 W54
$DISCON_ST L%1.dir U0
pause
$ODC L%1.dir L83%2.dir(2,0)
WUDD 5000 %2.dir
pause
pause
pause
$SNV Q4 W1 W6 W54


Update LED and UDD status when Control Room station activates "Listen-In" feature. Mute the microphone


IND %1.phy %1.dak(E44%2.dir(2,0)) 2 1
WUDD 5000 %chg(44%2.dir(2,0),0)
IF %chg(1,0)
$DIP L%1.dir "auo 8"
ENDIF


Audio Recording event

Event Triggered by 45xx codes



IF %udd(1%2.dir(2,0))
$REC L83%2.dir(2,0) U0
IND %1.phy %1.dak(E45%2.dir(2,0)) 1 3 OFF
WUDD 1%2.dir(2,0) 0
stop
ENDIF
IF %udd(%2.dir(2,0))
$REC L83%2.dir(2,0) U1
IND %1.phy %1.dak(E45%2.dir(2,0)) 1 3 ON
WUDD 1%2.dir(2,0) 1
stop
ENDIF
pause
$DTS L%1.dir 'Rec. not avail.' U1
$DTS L%1.dir 'Call not active' U2


Reset UDD variables at ICX System startup

At ICX startup all UDD flags are reset


WUDD 5000 0
tmp 0 "0"
LOOP
tmp 0 "%op(%tmp(0),+,1)"
WUDD %tmp(0) 0
IF %op(%tmp(0),=,20)
BREAK
ENDIF
ENDLOOP
tmp 1 "100"
LOOP
tmp 1 "%op(%tmp(1),+,1)"
WUDD %tmp(1) 0
IF %op(%tmp(1),=,120)
BREAK
ENDIF
ENDLOOP


The use of UDD variables

UDDs are used to store various status information:

  • UDD 1 - 20: Call status, one UDD per intercom pair: 0 = Call not active. 1 = Call is active.
  • UDD 101 - 120: Recordig status, one UDD per intercom pair: 0 = Recording not active. 1 = Recording active.
  • UDD 5000: 0 = Listen-In not active. When Listen-In is active the UDD stores which pair is monitored. (44xx, where xx is the pair).