Toggle Applications

This article describes different applications where the common scenario is to toggle a feature on/off using just a DAK key (or station input). Some features have options that gives additional opportunities.

In the examples below the AlphaCom data commands used are hyperlinked. Common for many of them is:

$WUDD

The DAK as RCI event is the preferred event for most of the applications.

Conversation

Toggle between Call and Cancel: pressing DAK key 1 sets up a call to station 101. Second press cancels the call. A second event must be created to handle the scenario where 101 initiates the call , or ends the call.

First DAK key press: Call.
Second press: Cancel

Action commands:

IF %udd(%1.phy)
$C L%1.dir
WUDD %1.phy 0
STOP
ENDIF
$CALL L%1.dir L101
WUDD %1.phy 1

Adjust UDD if call initiated or ended from the other station

Action command:

WUDD %1.phy %chg(1,0)

The same DAK can also answer an incoming call in private mode. Then the following event must be added:

Adjust UDD if call initiated or ended from the other station

Add some commands to the top of the initial DAK as RCI event, making it look like this:

IF %op(%udd(%1.phy),=,2)
$M L%1.dir
pause
$MREL L%1.dir
WUDD %1.phy 1
STOP
ENDIF
IF %udd(%1.phy)
$C L%1.dir
WUDD %1.phy 0
STOP
ENDIF
$CALL L%1.dir L101
WUDD %1.phy 1

For more details see $CALL, $C, $M, $MREL and pause

Call Request

Toggle between Call Request and Cancel Call Request: Pressing the DAK key the first time sends a Call Request to station 101 in the example. Second press cancels the call request. A second event must be created to handle the scenario where 101 answers the call request, or cancels it.

First press: Make a Call Request to 101
Second press: Cancel the Call Request

Action commands:

IF %udd(%1.phy)
$CANM L%1.dir L101
WUDD %1.phy 0
STOP
ENDIF
$SM L%1.dir L101
WUDD %1.phy 1

Reset UDD when station is no longer in Call Request mode (i.e. the Call Request is for any reason removed)

Action commands:

WUDD %2.phy 0

To add the possibility to answer incoming calls in private using the same DAK, see the Conversation application example.

For more details see $CANM, $SM and Call Request

Audio Program

Toggle between program on and program off. The example shows program 1 (801).

First press: make the station listen to program 1 (801)
Second press: Turn listening to program off

Action commands:

IF %udd(%1.phy)
$PROG L%1.dir LV
WUDD %1.phy 0
STOP
ENDIF
$PROG L%1.dir L801
WUDD %1.phy 1

Stepping through several programs can be performed by using the step codes 790 and 791 configured in the DAK settings:

790: Step to next program
791: Step to previous program

An event can also be created to do this. The example below uses DAK 4 for stepping to next program, and DAK 5 for stepping to previous program.

DAK4 (or input 4) activated: Step to next program
DAK5 (or input 5) activated: Step to previous program

Action commands:

IF %op(%sev,=,4)
$DD L%1.dir L790
ENDIF
IF %op(%sev,=,5)
$DD L%1.dir L791
ENDIF

For more details see $PROG and Audio Program

Transfer

Toggle between Transfer on and Transfer off. The example shows transferring calls to directory number 101.

First press: Activate call transfer to 101
Second press: Deactivate transfer

Action commands:

IF %udd(%1.phy)
$TRF L%1.dir ""
WUDD %1.phy 0
STOP
ENDIF
$TRF L%1.dir L101
WUDD %1.phy 1

Toggle between Call Request Transfer on and Call Request transfer off. The example shows transferring Call Requests to directory number 101.

First press: Activate Call Request transfer to 101
Second press: Deactivate Call Request transfer

Action commands:

IF %udd(%1.phy)
$SCRT L%1.dir
WUDD %1.phy 0
STOP
ENDIF
$SCRT L%1.dir L101
WUDD %1.phy 1

Option: If using a station with LED indications on the DAK keys (i.e. CRM-V or ECPIR-3P) the LED can be switched on and off to show status of the transfer. Change the action commands for the transfer event like this: (example shows red LED)

IF %udd(%1.phy)
$TRF L%1.dir ""
WUDD %1.phy 0
IND %1.phy %1.dir(i%2.dir) 1 1 OFF
STOP
ENDIF
$TRF L%1.dir L101
WUDD %1.phy 1
IND %1.phy %1.dir(i%2.dir) 1 1 ON

For more details see $TRF, $SCRT and IND

Simplex Conference

Toggle between joining a simplex conference (SX), and leaving it. The example shows joining/leaving SX1 (8201).

First press: Join Simplex Conference 1 (8201)
Second press: Leave the Simplex Conference

Action commands:

IF %udd(%1.phy)
$CONF L%1.dir LV
WUDD %1.phy 0
STOP
ENDIF
$CONF L%1.dir L8201
WUDD %1.phy 1

For more details see $CONF

Open Duplex Conference

Toggle between joining a open duplex conference (ODC), and leaving it. The example shows joining/leaving ODC1 (8301).

The $ODC command as an inbuilt toggle function, joining or leaving the conference depending on current status

Action command:

$ODC L%1.dir L8301 U2

For more details see $ODC

Volume adjustment

Stepping the volume in a circle using just one button. After max volume, the next step is minimum volume.

Activating the DAK (or an input) increments the volume by 1

Action commands:

IF %op(%vol(%1.phy),=,9)
$VOL L%1.dir U0
STOP
ENDIF
$VOL L%1.dir U%op(%vol(%1.phy),+,1)

Alternatively the volume stepping can be in double rate, incrementing the volume by two for each button press:

Action commands:

IF %op(%vol(%1.phy),=,9)
$VOL L%1.dir U1
STOP
ENDIF
$VOL L%1.dir U%op(%vol(%1.phy),+,2)

Using a station with two buttons (or two inputs) assigning one for volume up, and one for volume down:

Adjusting volume up when pressing DAK4 (input4)

Action commands:

IF %op(%vol(%1.phy),=,9)
STOP
ENDIF
$VOL L%1.dir U%op(%vol(%1.phy),+,1)

Adjusting volume down when pressing DAK5 (input5)

Action commands:

IF %op(%vol(%1.phy),=,0)
STOP
ENDIF
$VOL L%1.dir U%op(%vol(%1.phy),-,1)

For more details see VOL