Dynamic group call

Operation (CRM IV and CRM V)

• Press a dedicated "Group Configursation" DAK key. The red led in key starts flashing, and the Dynamic Group is emptied.
• Select stations or local groups to be included by pressing the associated DAK keys. A steady green led in the keys indicates that the stations/groups are included
• Press the "Group Configuration" button again, and the group call is activated (the ding-dong chime is played). Pressing the `M`-key opens the microphone.
• The green leds continue to be lit during the group call
• Cancel the group call by pressing the `C`-key. The green LEDs are turned off.

For best performance it is recommended to use CRM V station or ECPIR-3P panel, as these devices have buttons with LEDs showing status.

Software requirements

• ICX: Any version
• AlphaCom: 13.0.3. or later

Programming

• Assign directory number 9535 to DAK 1 of the operator station. This is the Group Configuration button. Directory number 9535 is included by default.

• Each operator station is assigned its own Dynamic Group Call by entering the Dynamic Group Call number in the User Defined Parameter (%1.EXP) field of the operator.
• Include all operator stations that should have feature in UDP group 1. Name the UDP group e.g. "Operators".

DynGrp UDP.PNG

Event Handler configuration

In AlphaPro, go to Exchange and System -> Events, press Insert and create the following events:

---

Event 1

-> This event will be triggered when the "Group Config." button is pressed for the first time.

Event Owner:	Stations w/ UDP Id: 1 (The CRM stations)
Event type:	15 – Event Trigger
Subevent:	0
When change to:	ON or OFF
When related to:	Directory Number, Id: 9535
Action:	IND %1.phy %1.dak(I%2.dir) 1 3	Turn ON + flash the red LED of the Group Config. button

---

Event 2

-> This event will be triggered each time a match is found in the directory table (after the "Group Config." button has been pressed for the first time.)

-> E.g. pressing a DAK-key with a directorynumber stored in it, will call this event (%2 will contain the directory number of the DAK key).

-> This event keeps being triggered until disconnected.

Event Owner:	Stations w/ UDP, Id: 1 (The CRM stations)
Event type:	25 – Event trigger with parameter
Subevent:	0
When change to:	ON or OFF
When related to:	All
Action:	IF %sgm(%2.phy,%1.exp(2))	If station is already member of this group, execute next lines.
		sgm = Station Group Member, %2.phy = station phys addr., %1.exp(2) = last 2 digits of UDP %1.exp value.
	IND %1.phy %1.dak(I%2.dir) 2 3 OFF	Station was member and will be removed from group, so switch OFF green flashing LED.
	ENDIF
	IF %op(%sgm(%2.phy,%1.exp(2)),=,0)	If station is not yet a member of this group, execute next lines.
		sgm = Station Group Member, %2.phy = station phys addr., %1.exp(2) = last 2 digits of UDP %1.exp value.
	IND %1.phy %1.dak(I%2.dir) 2 3 ON	Station was not a member and will be added to the group, so switch ON green flashing LED.
	ENDIF
	$GRM L%2.dir NG%1.exp(2) U2	Group Membership Toggle (this will add/remove the station to the group)
	IF %op(%2.dir,=,9535)	If the Group Config button is pressed, execute next lines (this is the 2nd time that the Group Config. button is pressed, so stop with the station selection phase and start the Group Call phase)
	$DISCON_ST L%1.dir 0	Disconnect this CRM station in order to stop this event being triggered.
	IND %1.phy %1.dak(I%2.dir) 2 3 OFF	Switch OFF the flashing green LED in the Group Config. Button. This LED was switched ON by pressing the button while Event 2 was active.
	PAUSE	Allow the system to settle (each Pause is 100 msec delay)
	PAUSE
	PAUSE
	$DD L%1.dir L%1.exp	DD = Dial Digits. Now setup a call from this CRM station (%1.dir) to the groupnumber specified in the UDP settings (%1.exp)
	ENDIF

---

Event 3

-> This event is triggered at the end of each conversation (by pressing the 'C' key)

Event Owner:	Stations w/ UDP, Id: 1 (The CRM stations)
Event type:	08 – Conversation - Outgoing
Subevent:	0
When change to:	OFF
When related to:	All
Action:	IF %op(%2.dir,=,%1.exp)	If the ended conversation was for this group (%1.exp), execute the next lines.
	IF %gns(%1.exp(2),0)	If station is member of group, execute next line.
		gns = Group Next Station. %1.exp(2) returns the last two digits of the groupnumber = Group Index Number.
		%gns(%1.exp(2),0) returns the physical station number of first member in the group, if no members in group, it returns 0.
	$ER U15 U1 U1 U1 N%gns(%1.exp(2),0) U3 %1.ref	Launch the next Event (Event 4).
		$ER = Event Report. %gns(%1.exp(2),0) = Owner, %1.ref = Related To
	ENDIF
	ENDIF

---

Event 4

-> This Event is triggered by the previous event (Event 3).

-> This Event will remove all stations from the group and switch OFF the green flashing LED's on the DAK keys of this CRM station where the group member stations are stored.

Event Owner:	Stations w/ UDP, Id: 8 (All stations)
Event type:	15 – Event Trigger
Subevent:	1 (NOTE: Subtype 1, NOT 0)
When change to:	ON
When related to:	All
Action:	$GRM N%gns(%2.exp(2),0) NG %2.exp(2) U0	Remove station from group
		%gns(%2.exp(2),0) returns the physical station number of the first member in the group, if no members are left in the group, it returns 0.
		%2.exp(2) returns the last two digits of the groupnumber = Group Index Number.
	IND %2.phy %2.dak(I%1.dir) 2 3 OFF	Switch OFF the green flashing LED of the DAK-key where this station is stored
	PAUSE	Allow the system to settle (each Pause is 100 msec delay)
	IF %gns(%2.exp(2),0)	Check if more stations are member of this group. If yes, execute next line.
	$ER U15 U1 U1 U1 N%gns(%2.exp(2),0) U3 %2.ref	Re-launch this same event (loop).
		$ER = Event Report. %gns(%2.exp(2),0) = Owner, %2.ref = Related To
	ENDIF

---