Dynamic group call

Operation (CRM IV and CRM V)

• Press a dedicated "Group Config." DAK key. The red led in key starts flashing
• Select subscribers to be included/excluded (toggle function) by pressing the assosiated DAK keys. A flashing green led in the keys indicates that the stations are included
• Press the "Group Config." button again, the group call is now activated. The red led in the DAK key stops flashing. Now the group call is activated (the ding-dong chime is played) and pressing the `M`-key opens the microphone.
• The green leds continue to flash during the group call
• Cancel the group call by pressing the `C`-key. All members will be removed from the group, and the green leds stop flashing.

It is not neccessary to use CRM-IV or CRM V stations, but with regular stations you will not get LED feedback on group call inclusion/exclusion.

LIMITATION: You can only include subscribers, you cannot include groups!

Programming

• Software requirement: AMC 8.26 or later

• In AlphaPro, Directory & Features, create a directory number, feature 95/0. Directory number 9535 is included by default. Program the "Group Config." DAK button to 9535.

• Each CRM station must be assigned its own group call that nobody else uses. The directory number of the group call must be changed so that the two last digits are identical to the group index number. Example:
  • Group 2 = 8502
  • Group 3 = 8503
  • Group 4 = 8504
  • Group 10 = 8510

So if you have 3 CRM stations, you need to program 3 group calls (e.g. 8502, 8503 and 8504).

• Enter the group call directory number in the User Defined Parameter (%1.EXP) field of each CRM-IV. In AlphaPro, Users & Stations -> UDP -> User Defined Parameter (%1.EXP). For the above example, CRM station 1 will have (%1.EXP)=8502, CRM station 2 will have (%1.EXP)=8503 and CRM station 3 will have (%1.EXP)=8504.
• Put all CRM’s that should have Dynamic group call feature in UDP group 1. Name this UDP group : "The CRM stations".

Event Handler configuration

In AlphaPro, go to Exchange and System -> Events, press Insert and create the following events:

---

Event 1

-> This event will be triggered when the "Group Config." button is pressed for the first time.

Event Owner:	Stations w/ UDP Id: 1 (The CRM stations)
Event type:	15 – Event Trigger
Subevent:	0
When change to:	ON or OFF
When related to:	Directory Number, Id: 9535
Action:	IND %1.phy %1.dak(I%2.dir) 1 3	Turn ON + flash the red LED of the Group Config. button

---

Event 2

-> This event will be triggered each time a match is found in the directory table (after the "Group Config." button has been pressed for the first time.)

-> E.g. pressing a DAK-key with a directorynumber stored in it, will call this event (%2 will contain the directory number of the DAK key).

-> This event keeps being triggered until disconnected.

Event Owner:	Stations w/ UDP, Id: 1 (The CRM stations)
Event type:	25 – Event trigger with parameter
Subevent:	0
When change to:	ON or OFF
When related to:	All
Action:	IF %sgm(%2.phy,%1.exp(2))	If station is already member of this group, execute next lines.
		sgm = Station Group Member, %2.phy = station phys addr., %1.exp(2) = last 2 digits of UDP %1.exp value.
	IND %1.phy %1.dak(I%2.dir) 2 3 OFF	Station was member and will be removed from group, so switch OFF green flashing LED.
	ENDIF
	IF %op(%sgm(%2.phy,%1.exp(2)),=,0)	If station is not yet a member of this group, execute next lines.
		sgm = Station Group Member, %2.phy = station phys addr., %1.exp(2) = last 2 digits of UDP %1.exp value.
	IND %1.phy %1.dak(I%2.dir) 2 3 ON	Station was not a member and will be added to the group, so switch ON green flashing LED.
	ENDIF
	$GRM L%2.dir NG%1.exp(2) U2	Group Membership Toggle (this will add/remove the station to the group)
	IF %op(%2.dir,=,9535)	If the Group Config button is pressed, execute next lines (this is the 2nd time that the Group Config. button is pressed, so stop with the station selection phase and start the Group Call phase)
	$DISCON_ST L%1.dir 0	Disconnect this CRM station in order to stop this event being triggered.
	IND %1.phy %1.dak(I%2.dir) 2 3 OFF	Switch OFF the flashing green LED in the Group Config. Button. This LED was switched ON by pressing the button while Event 2 was active.
	PAUSE	Allow the system to settle (each Pause is 100 msec delay)
	PAUSE
	PAUSE
	$DD L%1.dir L%1.exp	DD = Dial Digits. Now setup a call from this CRM station (%1.dir) to the groupnumber specified in the UDP settings (%1.exp)
	ENDIF

---

Event 3

-> This event is triggered at the end of each conversation (by pressing the 'C' key)

Event Owner:	Stations w/ UDP, Id: 1 (The CRM stations)
Event type:	08 – Conversation - Outgoing
Subevent:	0
When change to:	OFF
When related to:	All
Action:	IF %op(%2.dir,=,%1.exp)	If the ended conversation was for this group (%1.exp), execute the next lines.
	IF %gns(%1.exp(2),0)	If station is member of group, execute next line.
		gns = Group Next Station. %1.exp(2) returns the last two digits of the groupnumber = Group Index Number.
		%gns(%1.exp(2),0) returns the physical station number of first member in the group, if no members in group, it returns 0.
	$ER U15 U1 U1 U1 N%gns(%1.exp(2),0) U3 %1.ref	Launch the next Event (Event 4).
		$ER = Event Report. %gns(%1.exp(2),0) = Owner, %1.ref = Related To
	ENDIF
	ENDIF

---

Event 4

-> This Event is triggered by the previous event (Event 3).

-> This Event will remove all stations from the group and switch OFF the green flashing LED's on the DAK keys of this CRM station where the group member stations are stored.

Event Owner:	Stations w/ UDP, Id: 8 (All stations)
Event type:	15 – Event Trigger
Subevent:	1 (NOTE: Subtype 1, NOT 0)
When change to:	ON
When related to:	All
Action:	$GRM N%gns(%2.exp(2),0) NG %2.exp(2) U0	Remove station from group
		%gns(%2.exp(2),0) returns the physical station number of the first member in the group, if no members are left in the group, it returns 0.
		%2.exp(2) returns the last two digits of the groupnumber = Group Index Number.
	IND %2.phy %2.dak(I%1.dir) 2 3 OFF	Switch OFF the green flashing LED of the DAK-key where this station is stored
	PAUSE	Allow the system to settle (each Pause is 100 msec delay)
	IF %gns(%2.exp(2),0)	Check if more stations are member of this group. If yes, execute next line.
	$ER U15 U1 U1 U1 N%gns(%2.exp(2),0) U3 %2.ref	Re-launch this same event (loop).
		$ER = Event Report. %gns(%2.exp(2),0) = Owner, %2.ref = Related To
	ENDIF

---